Fediversity/deployment/data-model.nix

{
  lib,
  config,
  options,
  inputs,
  ...
}:
let
  inherit (lib) mkOption types;
  inherit (lib.types)
    attrsOf
    attrTag
    deferredModuleWith
    submodule
    optionType
    functionTo
    ;

  functionType = import ./function.nix { inherit lib; };
  application-resources = submodule {
    options.resources = mkOption {
      # TODO: maybe transpose, and group the resources by type instead
      type = attrsOf (
        attrTag (
          lib.mapAttrs (_name: resource: mkOption { type = submodule resource.request; }) config.resources
        )
      );
    };
  };
  nixops4Deployment = types.deferredModuleWith {
    staticModules = [
      inputs.nixops4.modules.nixops4Deployment.default

      {
        _class = "nixops4Deployment";
        _module.args = {
          resourceProviderSystem = builtins.currentSystem;
          resources = { };
        };
      }
    ];
  };
in
{
  options = {
    resources = mkOption {
      description = "Collection of deployment resources that can be required by applications and policed by hosting providers";
      type = attrsOf (
        submodule (
          { ... }:
          {
            _class = "fediversity-resource";
            options = {
              description = mkOption {
                description = "Description of the resource to help application module authors and hosting providers to work with it";
                type = types.str;
              };
              request = mkOption {
                description = "Options for declaring resource requirements by an application, a description of how the resource is consumed or accessed";
                type = deferredModuleWith { staticModules = [ { _class = "fediversity-resource-request"; } ]; };
              };
              policy = mkOption {
                description = "Options for configuring the resource policy for the hosting provider, a description of how the resource is made available";
                type = deferredModuleWith {
                  staticModules = [
                    (policy: {
                      _class = "fediversity-resource-policy";
                      options.resource-type = mkOption {
                        description = "The type of resource this policy configures";
                        type = types.optionType;
                      };
                      # TODO(@fricklerhandwerk): we may want to make the function type explict here: `request -> resource-type`
                      # and then also rename this to be consistent with the application's resource mapping
                      options.apply = mkOption {
                        description = "Apply the policy to a request";
                        type = functionTo policy.config.resource-type;
                      };
                    })
                  ];
                };
              };
            };
          }
        )
      );
    };
    applications = mkOption {
      description = "Collection of Fediversity applications";
      type = attrsOf (
        submodule (application: {
          _class = "fediversity-application";
          options = {
            description = mkOption {
              description = "Description to be shown in the application overview";
              type = types.str;
            };
            module = mkOption {
              description = "Operator-facing configuration options for the application";
              type = deferredModuleWith { staticModules = [ { _class = "fediversity-application-config"; } ]; };
            };
            implementation = mkOption {
              description = "Mapping of application configuration to deployment resources, a description of what an application needs to run";
              type = application.config.config-mapping.function-type;
            };
            # TODO(@fricklerhandwerk): this needs a better name, it's just the type
            config-mapping = mkOption {
              description = "Function type for the mapping from application configuration to required resources";
              type = functionType;
              readOnly = true;
              default = {
                input-type = submodule application.config.module;
                output-type = application-resources;
              };
            };
          };
        })
      );
    };
    environments = mkOption {
      description = "Run-time environments for Fediversity applications to be deployed to";
      type = attrsOf (
        submodule (environment: {
          _class = "fediversity-environment";
          options = {
            resources = mkOption {
              description = ''
                Resources made available by the hosting provider, and their policies.

                Setting this is optional, but provides a place to declare that information for programmatic use in the resource mapping.
              '';
              # TODO: maybe transpose, and group the resources by type instead
              type = attrsOf (
                attrTag (
                  lib.mapAttrs (_name: resource: mkOption { type = submodule resource.policy; }) config.resources
                )
              );
            };
            implementation = mkOption {
              description = "Mapping of resources required by applications to available resources; the result can be deployed";
              type = environment.config.resource-mapping.function-type;
            };
            resource-mapping = mkOption {
              description = "Function type for the mapping from resources to a (NixOps4) deployment";
              type = functionType;
              readOnly = true;
              default = {
                input-type = application-resources;
                output-type = nixops4Deployment;
              };
            };
          };
        })
      );
    };
    configuration = mkOption {
      description = "Configuration type declaring options to be set by operators";
      type = optionType;
      readOnly = true;
      default = submodule (configuration: {
        options = {
          enable = lib.mkEnableOption {
            description = "your Fediversity configuration";
          };
          applications = lib.mapAttrs (
            _name: application:
            mkOption {
              description = application.description;
              type = submodule application.module;
              default = { };
            }
          ) config.applications;
          required-resources = mkOption {
            description = "The deployment's required resources by application";
            type = submodule {
              options = lib.mapAttrs (
                name: _application:
                mkOption {
                  description = "Resources required for ${name}";
                  type = config.applications.${name}.config-mapping.output-type;
                }
              ) config.applications;
            };
            readOnly = true;
            default = lib.mapAttrs (
              # FIXME: in nix-unit invoking the implementation somehow triggers an infinite recursion,
              # tho my trace statements so far got triggered just once
              name: application-settings: (config.applications.${name}.implementation application-settings).output
            ) configuration.config.applications;
          };
        };
      });
    };
    deployments = mkOption {
      description = "Deployment of a configuration of applications to a run-time environment.";
      type = attrsOf (
        submodule (deployment: {
          options = {
            configuration = mkOption {
              description = "Configuration to be deployed";
              type = config.configuration;
            };
            environment = mkOption {
              description = "The run-time environment to deploy to";
              type = options.environments.type.nestedTypes.elemType;
            };
            # TODO(@fricklerhandwerk): maybe this should be a separate thing such as `fediversity-setup`,
            # which makes explicit which applications and environments are available.
            # then the deployments can simply be the result of the function application baked into this module.
            deployment = mkOption {
              description = "Generate a deployment from a configuration, by applying an environment's resource policies to the applications' resource mappings";
              type = deployment.config.environment.resource-mapping.output-type;
              readOnly = true;
              # TODO: check cfg.enable.true
              default =
                (deployment.config.environment.implementation deployment.config.configuration.required-resources)
                .output;
            };
          };
        })
      );
    };
  };
}