Fediversity/deployment/data-model-test.nix

let
  inherit (import ../default.nix { }) pkgs inputs;
  inherit (pkgs) lib;
  inherit (lib) mkOption;
  eval =
    module:
    (lib.evalModules {
      specialArgs = {
        inherit inputs;
      };
      modules = [
        module
        ./data-model.nix
      ];
    }).config;
in
{
  _class = "nix-unit";

  test-eval = {
    expr =
      let
        fediversity = eval (
          { config, ... }:
          {
            config = {
              applications.hello =
                { ... }:
                {
                  description = ''Command-line tool that will print "Hello, world!" on the terminal'';
                  module =
                    { ... }:
                    {
                      options = {
                        enable = lib.mkEnableOption "Hello in the shell";
                      };
                    };
                  implementation =
                    cfg:
                    lib.optionalAttrs cfg.enable {
                      dummy.login-shell.packages.hello = pkgs.hello;
                    };
                };
            };
            options = {
              example-configuration = mkOption {
                type = config.configuration;
                readOnly = true;
                default = {
                  enable = true;
                  applications.hello.enable = true;
                };
              };
            };
          }
        );
      in
      {
        inherit (fediversity)
          example-configuration
          ;
      };
    expected = {
      example-configuration = {
        enable = true;
        applications.hello.enable = true;
      };
    };
  };
}