Fediversity/deployment/data-model.nix

{
  lib,
  config,
  ...
}:
let
  inherit (lib)
    attrNames
    mapAttrs
    mkOption
    genAttrs
    ;
  inherit (lib.types)
    attrsOf
    attrTag
    deferredModule
    mergeTypes
    nullOr
    submoduleWith
    submodule
    str
    ;
  provider = mkOption {
    description = "The NixOS module of a provider";
    type = deferredModule;
    default = {
      _class = "nixos";
    };
  };
  runtime-environment = attrTag (
    mapAttrs
      (
        name:
        option@{ type, ... }:
        mkOption (
          option
          // {
            type = mergeTypes type (submodule {
              options.module = mkOption {
                description = "The NixOS module of the provider";
                type = deferredModule;
                default = config.providers.${name};
                readOnly = true;
              };
            });
          }
        )
      )
      {
        vm = {
          description = "A VM to deploy to.";
          type = submodule {
            options = {
            };
          };
        };
        ssh-host = {
          description = "A single host to deploy to by SSH.";
          type = submodule {
            options = {
              ssh = mkOption {
                description = "SSH connection info";
                type = submodule {
                  options = {
                    host = mkOption {
                      description = "the host to access by SSH";
                      type = str;
                    };
                    username = mkOption {
                      description = "the SSH user to use";
                      type = nullOr str;
                      default = null;
                    };
                    authentication = mkOption {
                      description = "authentication method";
                      type = attrsOf (attrTag {
                        private-key = mkOption {
                          description = "path to the user's SSH private key";
                          type = str;
                          example = "/root/.ssh/id_ed25519";
                        };
                        password = mkOption {
                          description = "SSH password";
                          # TODO: mark as sensitive
                          type = str;
                        };
                      });
                    };
                  };
                };
              };
            };
          };
        };
      }
  );
  resource = attrTag {
    runtime-environment = mkOption {
      description = "A run-time environment one may deploy a NixOS configuration to.";
      type = runtime-environment;
    };
  };
  application = submoduleWith {
    description = "A Fediversity application";
    modules = [
      {
        options = {
          module = mkOption {
            description = ''
              The NixOS module to configure the application.
            '';
            type = deferredModule;
          };
        };
      }
    ];
  };
  deployment = submoduleWith {
    description = "A deployment of a configuration of applications to a run-time environment";
    modules = [
      {
        options = {
          # the `applications` option consists of configuration for the above applications
          module = mkOption {
            description = ''
              Configuration to be deployed
            '';
            type = deferredModule;
          };
          runtime-environment = mkOption {
            description = "The run-time environment to deploy to";
            type = runtime-environment;
          };
        };
      }
    ];
  };
  migration = submoduleWith {
    description = "Migration of a Fediversity deployment to a Fediversity run-time environment";
    modules = [
      {
        options = {
          deployment = mkOption {
            description = "Deployment to migrate";
            type = deployment;
          };
          runtime-environment = mkOption {
            description = "Run-time environment to migrate the deployment to";
            type = runtime-environment;
          };
        };
      }
    ];
  };
in
{
  options = {
    providers = mkOption {
      description = "Collection of providers for run-time environments to deploy applications to";
      type = attrTag (genAttrs (attrNames runtime-environment.nestedTypes) (_: provider));
    };
    resources = mkOption {
      description = "Collection of resources for use in Fediversity applications";
      type = attrsOf resource;
    };
    applications = mkOption {
      description = "Collection of (available) Fediversity applications";
      type = attrsOf application;
    };
    deployments = mkOption {
      description = "Deployment of a configuration of applications to a run-time environment";
      type = attrsOf deployment;
    };
    # XXX should this be more ephemeral than something that just.. exists?
    migrations = mkOption {
      description = "Migrations from Fediversity deployments to Fediversity run-time environments";
      type = attrsOf migration;
    };
  };
}