{
  lib,
  config,
  inputs,
  pkgs,
  ...
}:
let
  inherit (lib) mkOption types;
  inherit (lib.types)
    attrTag
    attrsOf
    deferredModuleWith
    functionTo
    nullOr
    optionType
    raw
    str
    submodule
    ;
  toBash =
    v:
    lib.replaceStrings [ "\"" ] [ "\\\"" ] (
      if lib.isPath v || builtins.isNull v then
        toString v
      else if lib.isString v then
        v
      else
        lib.strings.toJSON v
    );

  functionType = submodule ./function.nix;
  application-resources = submodule {
    options.resources = mkOption {
      # TODO: maybe transpose, and group the resources by type instead
      type = attrsOf (
        attrTag (
          lib.mapAttrs (_name: resource: mkOption { type = submodule resource.request; }) config.resources
        )
      );
    };
  };
  nixops4Deployment = types.deferredModuleWith {
    staticModules = [
      inputs.nixops4.modules.nixops4Deployment.default

      {
        _class = "nixops4Deployment";
        _module.args = {
          resourceProviderSystem = pkgs.system;
          resources = { };
        };
      }
    ];
  };
  nixos-configuration = mkOption {
    description = "A NixOS configuration.";
    type = raw;
  };
  host-ssh = mkOption {
    description = "SSH connection info to connect to a single host.";
    type = submodule {
      options = {
        host = mkOption {
          description = "the host to access by SSH";
          type = str;
        };
        username = mkOption {
          description = "the SSH user to use";
          type = nullOr str;
          default = null;
        };
        key-file = mkOption {
          description = "path to the user's SSH private key";
          type = nullOr str;
          example = "/root/.ssh/id_ed25519";
        };
        sshOpts = mkOption {
          description = "Extra SSH options (`-o`) to use.";
          type = types.listOf str;
          default = [ ];
          example = "ConnectTimeout=60";
        };
      };
    };
  };
  deployment-type = attrTag {
    ssh-host = mkOption {
      description = "A deployment by SSH to update a single existing NixOS host.";
      type = submodule (ssh-host: {
        options = {
          system = mkOption {
            description = "The architecture of the system to deploy to.";
            type = types.str;
          };
          inherit nixos-configuration;
          ssh = host-ssh;
          module = mkOption {
            description = "The module to call to obtain the NixOS configuration from.";
            type = types.str;
          };
          args = mkOption {
            description = "The arguments with which to call the module to obtain the NixOS configuration.";
            type = types.attrs;
          };
          deployment-name = mkOption {
            description = "The name of the deployment for which to obtain the NixOS configuration.";
            type = types.str;
          };
          root-path = mkOption {
            description = "The path to the root of the repository.";
            type = types.path;
          };
          run = mkOption {
            type = types.package;
            # error: The option `ssh-deployment.ssh-host.run' is read-only, but it's set multiple times.
            # readOnly = true;
            default =
              let
                inherit (ssh-host.config)
                  system
                  ssh
                  module
                  args
                  deployment-name
                  root-path
                  ;
                inherit (ssh)
                  host
                  username
                  key-file
                  sshOpts
                  ;
                environment = {
                  key_file = key-file;
                  deployment_name = deployment-name;
                  root_path = root-path;
                  ssh_opts = sshOpts;
                  inherit
                    system
                    host
                    username
                    module
                    args
                    ;
                  deployment_type = "ssh-host";
                };
              in
              pkgs.writeShellScriptBin "deploy-ssh.sh" ''
                env ${
                  toString (lib.mapAttrsToList (k: v: "${k}=\"${toBash v}\"") environment)
                } bash ./deployment/run/ssh-single-host/run.sh
              '';
          };
        };
      });
    };
    nixops4 = mkOption {
      description = "A NixOps4 NixOS deployment. For an example, see https://github.com/nixops4/nixops4-nixos/blob/main/example/deployment.nix.";
      type = nixops4Deployment;
    };
  };
in
{
  options = {
    resources = mkOption {
      description = "Collection of deployment resources that can be required by applications and policed by hosting providers";
      type = attrsOf (
        submodule (
          { ... }:
          {
            _class = "fediversity-resource";
            options = {
              description = mkOption {
                description = "Description of the resource to help application module authors and hosting providers to work with it";
                type = types.str;
              };
              request = mkOption {
                description = "Options for declaring resource requirements by an application, a description of how the resource is consumed or accessed";
                type = deferredModuleWith { staticModules = [ { _class = "fediversity-resource-request"; } ]; };
              };
              policy = mkOption {
                description = "Options for configuring the resource policy for the hosting provider, a description of how the resource is made available";
                type = deferredModuleWith {
                  staticModules = [
                    (policy: {
                      _class = "fediversity-resource-policy";
                      options.resource-type = mkOption {
                        description = "The type of resource this policy configures";
                        type = types.optionType;
                      };
                      # TODO(@fricklerhandwerk): we may want to make the function type explicit here: `application-resources -> resource-type`
                      # and then also rename this to be consistent with the application's resource mapping
                      options.apply = mkOption {
                        description = "Apply the policy to a request";
                        type = functionTo policy.config.resource-type;
                      };
                    })
                  ];
                };
              };
            };
          }
        )
      );
    };
    applications = mkOption {
      description = "Collection of Fediversity applications";
      type = attrsOf (
        submodule (application: {
          _class = "fediversity-application";
          options = {
            description = mkOption {
              description = "Description to be shown in the application overview";
              type = types.str;
            };
            module = mkOption {
              description = "Operator-facing configuration options for the application";
              type = deferredModuleWith { staticModules = [ { _class = "fediversity-application-config"; } ]; };
            };
            implementation = mkOption {
              description = "Mapping of application configuration to deployment resources, a description of what an application needs to run";
              type = application.config.config-mapping.function-type;
            };
            resources = mkOption {
              description = "Compute resources required by an application";
              type = application.config.config-mapping.function-type;
              readOnly = true;
              default = application.config.config-mapping.apply;
            };
            # TODO(@fricklerhandwerk): this needs a better name
            config-mapping = mkOption {
              description = "Function type for the mapping from application configuration to required resources";
              type = functionType;
              readOnly = true;
              default = {
                input-type = submodule application.config.module;
                output-type = application-resources;
                implementation = application.config.implementation;
              };
            };
          };
        })
      );
    };
    environments = mkOption {
      description = "Run-time environments for Fediversity applications to be deployed to";
      type = attrsOf (
        submodule (environment: {
          _class = "fediversity-environment";
          options = {
            resources = mkOption {
              description = ''
                Resources made available by the hosting provider, and their policies.

                Setting this is optional, but provides a place to declare that information for programmatic use in the resource mapping.
              '';
              # TODO: maybe transpose, and group the resources by type instead
              type = attrsOf (
                attrTag (
                  lib.mapAttrs (_name: resource: mkOption { type = submodule resource.policy; }) config.resources
                )
              );
            };
            implementation = mkOption {
              description = "Mapping of resources required by applications to available resources; the result can be deployed";
              type = environment.config.resource-mapping.function-type;
            };
            resource-mapping = mkOption {
              description = "Function type for the mapping from resources to a deployment";
              type = functionType;
              readOnly = true;
              default = {
                input-type = submodule {
                  options = {
                    deployment-name = mkOption {
                      type = types.str;
                    };
                    required-resources = mkOption {
                      type = attrsOf application-resources;
                    };
                  };
                };
                output-type = deployment-type;
                implementation = environment.config.implementation;
              };
            };
            config-mapping = mkOption {
              description = "Mapping from a configuration to a deployment";
              type = functionType;
              readOnly = true;
              default = {
                input-type = submodule {
                  options = {
                    deployment-name = mkOption {
                      type = types.str;
                    };
                    configuration = mkOption {
                      type = config.configuration;
                    };
                  };
                };
                output-type = deployment-type;
                implementation =
                  {
                    deployment-name,
                    configuration,
                  }:
                  # TODO: check cfg.enable.true
                  let
                    required-resources = lib.mapAttrs (
                      name: application-settings: config.applications.${name}.resources application-settings
                    ) configuration.applications;
                  in
                  environment.config.resource-mapping.apply { inherit required-resources deployment-name; };
              };
            };
            # TODO(@fricklerhandwerk): maybe this should be a separate thing such as `fediversity-setup`,
            # which makes explicit which applications and environments are available.
            # then the deployments can simply be the result of the function application baked into this module.
            deployment = mkOption {
              description = "Generate a deployment from a configuration, by applying an environment's resource policies to the applications' resource mappings";
              type = environment.config.config-mapping.function-type;
              readOnly = true;
              default = environment.config.config-mapping.apply;
            };
          };
        })
      );
    };
    configuration = mkOption {
      description = "Configuration type declaring options to be set by operators";
      type = optionType;
      readOnly = true;
      default = submodule {
        options = {
          enable = lib.mkEnableOption {
            description = "your Fediversity configuration";
          };
          applications = lib.mapAttrs (
            _name: application:
            mkOption {
              description = application.description;
              type = submodule application.module;
              default = { };
            }
          ) config.applications;
        };
      };
    };
  };
}