{
  runNixOSTest,
  inputs,
  sources,
  system,
}:

let
  pkgs = import sources.nixpkgs-stable {
    inherit system;
    overlays = [ overlay ];
  };
  overlay = _: _: {
    inherit
      (import "${sources.proxmox-nixos}/pkgs" {
        craneLib = pkgs.callPackage "${sources.crane}/lib" { };
        # breaks from https://github.com/NixOS/nixpkgs/commit/06b354eb2dc535c57e9b4caaa16d79168f117a26,
        # which updates libvncserver to 0.9.15, which was not yet patched at https://git.proxmox.com/?p=vncterm.git.
        inherit pkgs;
        # not so picky about version for our purposes
        pkgs-unstable = pkgs;
      })
      proxmox-ve
      pve-ha-manager
      ;
  };
in
runNixOSTest {
  node.specialArgs = {
    inherit
      sources
      pkgs
      ;
  };
  imports = [
    ../../data-model.nix
    ../../function.nix
    ../common/nixosTest.nix
    ./nixosTest.nix
  ];
  _module.args = { inherit inputs sources; };
  inherit (import ./constants.nix)
    targetMachines
    pathToRoot
    pathFromRoot
    enableAcme
    ;
}