let
  inherit (import ../default.nix { }) pkgs inputs;
  inherit (pkgs) lib;
  eval =
    module:
    (lib.evalModules {
      specialArgs = {
        inherit inputs;
      };
      modules = [
        module
        ./data-model.nix
      ];
    }).config;
in
{
  test-eval = {
    expr =
      let
        example = eval (
          { config, ... }:
          {
            providers.single-ssh-host =
              { ... }:
              {
                system.stateVersion = "25.05";
              };
            resources.bar.runtime-environment.single-ssh-host = {
              ssh = {
                host = "localhost";
                username = "root";
                authentication.password = "";
              };
            };
            applications.foo.module =
              { pkgs, ... }:
              {
                environment.systemPackages = [
                  pkgs.hello
                ];
              };
            deployments.baz = {
              module = { };
              runtime-environment = config.resources.bar.runtime-environment;
            };
            migrations.boo = {
              deployment = config.deployments.baz;
              runtime-environment = config.resources.bar.runtime-environment;
            };
          }
        );
      in
      {
        has-provider = lib.isAttrs example.providers.single-ssh-host;
        has-resource = lib.isAttrs example.resources.bar.runtime-environment.single-ssh-host.module;
        has-application = lib.isAttrs example.applications.foo.module;
        has-deployment = lib.isAttrs example.deployments.baz.module;
        has-migration = lib.isAttrs example.migrations.boo.deployment;
      };
    expected = {
      has-provider = true;
      has-resource = true;
      has-application = true;
      has-deployment = true;
      has-migration = true;
    };
  };
}