let
  inherit (import ../default.nix { }) pkgs;
  inherit (pkgs) lib;
  eval =
    module:
    (lib.evalModules {
      modules = [
        module
        ./data-model.nix
      ];
    }).config;
in
{
  _class = "nix-unit";

  test-eval = {
    expr =
      let
        example = eval (
          { config, ... }:
          {
            runtime-configurations.single-ssh-host =
              { ... }:
              {
                system.stateVersion = "25.05";
              };
            runtime-environments.bar = {
              single-ssh-host = {
                ssh = {
                  host = "localhost";
                  username = "root";
                  authentication.password = "";
                };
              };
            };
            applications.foo = {
              module =
                { pkgs, ... }:
                {
                  environment.systemPackages = [
                    pkgs.hello
                  ];
                };
            };
            deployments.baz = {
              module = { };
              runtime-environment = config.runtime-environments.bar;
            };
            migrations.boo = {
              deployment = config.deployments.baz;
              runtime-environment = config.runtime-environments.bar;
            };
          }
        );
      in
      {
        has-runtime-configuration = lib.isAttrs example.runtime-configurations.single-ssh-host;
        has-runtime-environment = lib.isAttrs example.runtime-environments.bar.single-ssh-host.module;
        has-application = lib.isAttrs example.applications.foo.module;
        has-deployment = lib.isAttrs example.deployments.baz.module;
        has-migration = lib.isAttrs example.migrations.boo.deployment;
      };
    expected = {
      has-runtime-configuration = true;
      has-runtime-environment = true;
      has-application = true;
      has-deployment = true;
      has-migration = true;
    };
  };
}