{
  inputs,
  sources,
  lib,
  ...
}:

let
  inherit (import ./constants.nix) targetMachines pathToRoot pathFromRoot;
  eval =
    module:
    (lib.evalModules {
      specialArgs = {
        inherit inputs;
      };
      modules = [
        module
        ../../data-model.nix
      ];
    }).config;
  fediversity = eval (
    { ... }:
    {
      config = {
        environments.single-nixos-vm =
          { ... }:
          {
            implementation = requests: {
              input = requests;
              output =
                { providers, ... }:
                {
                  providers = {
                    inherit (inputs.nixops4.modules.nixops4Provider) local;
                  };
                  resources = lib.genAttrs targetMachines (nodeName: {
                    type = providers.local.exec;
                    imports = [
                      inputs.nixops4-nixos.modules.nixops4Resource.nixos
                      ../../data-model.nix
                      ../../function.nix
                      ../common/targetResource.nix
                    ];
                    _module.args = { inherit inputs sources; };
                    inherit nodeName pathToRoot pathFromRoot;
                    nixos.module =
                      { pkgs, ... }:
                      {
                        environment.systemPackages = [ pkgs.${nodeName} ];
                      };
                  });
                };
            };
          };
      };
    }
  );
in
fediversity.environments.single-nixos-vm.deployment {
  enable = true;
}