Fediversity/infra/flake-part.nix

{
  inputs,
  lib,
  ...
}:

let
  inherit (lib) attrValues concatLists mapAttrs;
  inherit (lib.attrsets) genAttrs;

  makeResource =
    vmName:
    { providers, ... }:
    {
      _module.args = { inherit inputs; };
      type = providers.local.exec;
      imports = [
        inputs.nixops4-nixos.modules.nixops4Resource.nixos
        ./common/procolixResource.nix
        (./. + "/${vmName}")
      ];
      procolixVm.name = vmName;
    };

  addDefaultDeployment =
    deployments: deployments // { default = concatLists (attrValues deployments); };

  makeDeployments = mapAttrs (
    _: vmNames:
    { providers, ... }:
    {
      providers.local = inputs.nixops4.modules.nixops4Provider.local;
      resources = genAttrs vmNames (vmName: makeResource vmName { inherit providers; });
    }
  );

in
{
  nixops4Deployments = makeDeployments (addDefaultDeployment {
    git = [
      "vm02116"
      "fedi300"
    ];
    web = [ "vm02187" ];
    other = [
      "vm02179"
      "vm02186"
    ];
  });
}